globals [a n r s x dl al sl maxdl fabric pin k m g l x0 FR maxl i moved c comptime
  trtlcnt sprngcnt outrcnt eqcnt q mesh]
turtles-own [d dis j nghbr turnnghbr dnghbr arcl maxarcl tempfx tempfy tempfz 
  deltax deltay deltaz slopex slopey slopez tempx tempy tempz movex movey movez 
  xac yac zac xvel yvel zvel]

to setup
  clear-all
  set s Scale
  set r 5 * s                      ;;radius
  setxyz 0 0 20                    ;;view point of observer
  set-default-shape turtles "dot"
  ask patches
  [
    if (pzcor = 5 and abs(pxcor) < r and abs(pycor) < r)
    [                              ;;patches on the plane z=5 each have a turtle
      sprout 1
    ]
  ]
end

to begin
  set n 1
  repeat 20
  [
    setxyz 0 n (20 - n)            ;;view point of observer
    set n n + 1
  ]
end

to count-equations
  set trtlcnt count turtles
  set sprngcnt count links
  set q 0
  ask turtles
  [set q q + count link-neighbors]
  set eqcnt 3 * q
end

to approx-circle
  set size 0.3
  set color white
  set d distancexyz 0 0 5
  if d > r                         ;;eliminate turtles and links that are
  [                                 ;outside of the circle
    die
  ]
end

to setup-quad                      ;;setup circular fabric with quadrangular mesh
  setup
  ask turtles
  [
    if (abs(pxcor) != r and abs(pycor) != r)  ;;all inside turtles link to
    [                                          ;neighbors, do not wrap
      create-links-with turtles-on neighbors6
    ]
    approx-circle
  ]
  set-constants
  ask turtles
  [
    set nghbr ([who] of link-neighbors)        ;;find neighbors
    set dnghbr no-turtles
  ]                            
  set-j                           ;;find order (from the fixed point to outer edges)
  set c count turtles with [j = r];;count outer mass points
  ask turtles
  [
    set i j                       ;;find mass point to constrain to
    set turnnghbr ([who] of link-neighbors with [j = i - 1])
  ]
  shrink                          ;;shrink down to circle with r=5
  count-equations
  set mesh 1
  reset-ticks
end

to setup-tri                      ;;sets up triangular mesh circle
  setup
  ask turtles
  [
    if (abs(pxcor) != r and abs(pycor) != r)  ;;all inside turtles link to
    [                                          ;neighbors, do not wrap
      create-links-with turtles-on neighbors
    ]
    approx-circle
  ]
  set-constants
  set-j                     ;;find order (from the fixed point to outer edges)
  set c count turtles with [j = r];;count outer mass points
  ask turtles
  [                             ;;find neighbors based on spring type
    set nghbr ([who] of link-neighbors with [distance myself = 1]);;structural neighbors
    set dnghbr ([who] of link-neighbors with [distance myself > 1]);;shear (diagonal)
    set i j
    set turnnghbr ([who] of link-neighbors with [j = i - 1]);;constrain neighbors
  ]
  shrink                      ;;shrink down to circle with r=5
  count-equations
  set mesh 2
  reset-ticks
end

to setup-arc
  clear-all
  set s Scale
  set r 5 * s                      ;;radius
  setxyz 0 0 20                ;;view point
  set-default-shape turtles "dot"
  set a Arc_Scale                  ;;controls the number of radial lines
  set n 1
  repeat r                         ;;creates inner circles, working outwards
  [
    crt a
    ask turtles
    [
      if (who >= a * (n - 1) and who <= a * n - 1) ;;new turtles
      [
        set j n                    ;;controls order of for constraints
        ifelse who < a * n - 1
        [
          create-link-with turtle (who + 1)  ;;new points create springs
        ]
        [
          create-link-with turtle (who - (a - 1))
        ]
      ]
    ]
    layout-circle sort (turtles with [j = n])  n  ;;new point set in a circle
    set n n + 1
  ]
  ask turtles
  [
    set arcl distance turtle first [who] of link-neighbors
    set maxarcl 1.1 * arcl
  ]                               ;;"arc length" for each circle
  crt 1                           ;;fixed point
  ask turtles with [j = 0]        ;;connect fixed point to closest points
  [
    create-links-with turtles with [j = 1]
  ]
  ask turtles with [j < r and j > 0]
  [
    create-link-with turtle (who + a)  ;;sets up springs along radial lines
  ]
  ask turtles
  [
    set zcor 5
    set size .3
    set color white
    set nghbr ([who] of link-neighbors)  ;;keep track of neighbors
    set i j
    set turnnghbr ([who] of link-neighbors with [j < i]) ;;for constraint
  ]
  set c count turtles with [j = r];; count outer mass points
  set-constants
  shrink
  count-equations
  set mesh 3
  reset-ticks
end

to set-constants
   set sl 1 / s                  ;;spring length
   set dl sqrt (2 * sl ^ 2)      ;;diagonal spring length
   set maxl 1.1 * sl             ;;maximum spring length
   set maxdl 1.1 * dl            ;;maximum diagonal spring length
   set g .25                     ;;gravity
   set m 1                       ;;mass
   set k .29                     ;;spring constant
   set FR Friction
   set fabric (turtles with [distancexyz 0 0 5 > .01]);;unfixed mass points
   set pin (turtles with [distancexyz 0 0 5 < .01])   ;;fixed mass point
   ask pin
   [
     set tempx 0                 ;;temporary values for fixed point
     set tempy 0
     set tempz 5
   ]
end

to shrink                        ;;controls resolution while maintaining r=5
  ask fabric
  [
    set xcor (1 / s) * xcor
    set ycor (1 / s) * ycor
  ]
end

to set-j
  ifelse mesh = 1
  [
    set i 1                        ;;begin nearest to the pin
    repeat r                       ;;for the entire radius
    [
      ask fabric
      [
        if (distancexyz 0 0 5 <= i and j = 0)  ;;if the distance is under
        [                           ;index amount and an index has not been assigned
          set j i                  ;;set the index
        ]
      ]
      set i i + 1                  ;;increase index for the next loop
    ]                               ;(working outwards)
  ]
  [                                ;;j for triangular mesh
      set i .5                     ;;begin nearest to the pin
    repeat r + 1                   ;;for the entire radius
    [
      ask fabric
      [
        if (distancexyz 0 0 5 <= i and j = 0)
        [
          set j (i - .5)           ;;set the index as an integer
        ]
      ]
      set i i + 1                  ;;work to the outside
    ]
  ] 
end

to move
  if ticks = 0 
  [
    begin
    reset-timer
  ]
  tick
  if mesh = 1                     ;;moves quadrangular mesh
  [
    ask fabric [calc-forces]       ;;calculates forces acting on each turtle
    ask turtles [calc-position]    ;;calculates and moves to new positions
    ask turtles [constrain]        ;;ensure springs aren't too long
  ]
  if mesh = 2                     ;;moves triangular mesh
  [ 
    ask fabric [calc-forces-tri]   ;;calculates forces acting on each turtle
    ask turtles [calc-position]    ;;calculates and moves to new positions
    ask turtles [constrain-tri]
  ]
  if mesh = 3
  [
    ask fabric [calc-forces-arc]   ;;calculates forces acting on each turtle
    ask turtles [calc-position]    ;;calculates and moves to new positions
    ask turtles [constrain-arc]
  ]
  set moved 0
  ask turtles with [j = r] [calc-change]
  if moved / c < 0.1
  [
    set comptime timer
    rotate
    stop
  ]
end

to rotate
  set n 1
  repeat 20
  [
    setxyz 0 (20 - n) n                    ;;view point of observer
    set n n + 1
  ]
end

to calc-change
  set movex xcor - movex
  set movey ycor - movey
  set movez zcor - movez
  set dis sqrt(movex ^ 2 + movey ^ 2 + movez ^ 2)
  set moved moved + dis
end

to calc-forces
  set tempFx 0                   ;;temporary forces, updated for each neighbor
  set tempFy 0
  set tempFz 0
  foreach nghbr                  ;;calculates the force each neighbor is applying
  [
    set l sl                     ;;desired length
    set d (distance turtle ?)    ;;distance
    if d = 0
    [
      stop
    ]
    set deltax (([xcor] of turtle ?) - xcor) ;;find position from neighbors
    set deltay (([ycor] of turtle ?) - ycor)
    set deltaz (([zcor] of turtle ?) - zcor)
    calc                         ;;calculates and updates forces
  ]
  calc-vel
end

to calc-forces-tri
  set tempFx 0                   ;;temporary forces, updated for each neighbor
  set tempFy 0
  set tempFz 0
  foreach nghbr                  ;;calculates the force each neighbor is applying
  [
    set l sl                     ;;desired length
    set d (distance turtle ?)    ;;distance
    if d = 0
    [
      stop
    ]
    set deltax (([xcor] of turtle ?) - xcor) ;;find position from neighbors
    set deltay (([ycor] of turtle ?) - ycor)
    set deltaz (([zcor] of turtle ?) - zcor)
    calc
  ]
  foreach dnghbr
  [
    set l dl                     ;;desired length
    set d (distance turtle ?)    ;;distance
    if d = 0
    [
      stop
    ]
    set deltax (([xcor] of turtle ?) - xcor) ;;find position from neighbors
    set deltay (([ycor] of turtle ?) - ycor)
    set deltaz (([zcor] of turtle ?) - zcor)
    calc
  ]
  calc-vel
end

to calc-forces-arc
  set tempFx 0                   ;;temporary forces, updated for each neighbor
  set tempFy 0
  set tempFz 0
  foreach nghbr                  ;;calculates the force each neighbor is applying
  [
    ifelse ([j] of turtle ? = j) ;;if neighbor lies along the same circle
    [
      set l arcl                 ;;use arclegnth
    ]
    [
      set l sl                   ;;otherwise, use usual spring length
    ]
    set d (distance turtle ?)    ;;distance
    if d = 0
    [
      stop
    ]
    set deltax (([xcor] of turtle ?) - xcor) ;;find position from neighbors
    set deltay (([ycor] of turtle ?) - ycor)
    set deltaz (([zcor] of turtle ?) - zcor)
    calc
  ]
  calc-vel
end

to calc
  set slopey (deltay / d)       ;;finds slopes
  set slopex (deltax / d)
  set slopez (deltaz / d)
  set tempFx (tempFx + ((k * (d - l)) * slopex) / m) ;;calculates x-component of force
  set tempFy (tempFy + ((k * (d - l)) * slopey) / m) ;;calculates y-component of force
  set tempFz (tempFz + ((k * (d - l)) * slopez) / m) ;;calculates z-component of force
end

to calc-vel                     ;;uses forces to calculate velocities
  set xac (tempFx)          ;;a=f/m
  set yac (tempFy)
  set zac (tempFz) - g * m  ;;include gravity after other forces are calculated
  set xvel ((1 - FR) * xvel + xac);;applies friction and calculates new velocity
  set yvel ((1 - FR) * yvel + yac)
  set zvel ((1 - FR) * zvel + zac)
end

to calc-position                ;;moves turtles to new positions using velocities
  if j = r
  [
    set movex xcor
    set movey ycor
    set movez zcor
  ]
  set tempx (xcor + xvel)       ;;calculates new position
  set tempy (ycor + yvel)
  set tempz (zcor + zvel)
  ifelse (tempx < min-pxcor or tempx > max-pxcor)
  [
    if tempx > max-pxcor        ;;if the new x-coordinate is outside the boundaries,
    [                            ;have it stop at the boundary
      set xcor max-pxcor
    ]
    if tempx < min-pxcor
    [
      set xcor min-pxcor
    ]
  ]
  [
    set xcor tempx              ;;otherwise, move normally
  ]
  ifelse (tempy < min-pycor or tempy > max-pycor)
  [
    if tempy > max-pycor        ;;if the new y-coordinate is outside the boundaries,
    [                            ;have it stop at the boundary
      set ycor max-pycor
    ]
    if tempy < min-pycor
    [
      set ycor min-pycor
    ]
  ]
  [
    set ycor tempy              ;;otherwise, move normally
  ]
  ifelse (tempz < min-pzcor or tempz > max-pzcor)
  [
    if tempz > max-pzcor        ;;if the new z-coordinate is outside the boundaries,
    [                            ;have it stop at the boundary
      set zcor max-pzcor
    ]
    if tempz < min-pzcor
    [
      set zcor min-pzcor
    ]
  ]
  [
    set zcor tempz               ;;otherwise, move normally
  ]
end

to constrain               ;;after turtles move, searches for over stretched springs
  set i 1                   ;and shrink them
  repeat r
  [
    ask turtles with [j = i]     ;;begins with turtles closest to the pin
      [
        foreach turnnghbr
        [
          set dis distance turtle ?  ;;how far is the turtle from that neighbor
          while [dis > maxl]      ;;if it is too far...
          [
            face turtle ?         ;;turn towards that neighbor...
            fd .005                    ;and move towards it until...
            set dis distance turtle ?  ;until the spring length is acceptable
          ]
        ]
      ]
      set i i + 1                 ;;work outwards
   ]
end

to constrain-tri                  ;;constrain procedure for triangular mesh
  set i 1
  repeat r
  [
    ask turtles with [j = i]      ;;begins with turtles closest to the pin
      [
        foreach turnnghbr
        [
          set dis distance turtle ? ;;how far is the turtle from that neighbor
          if member? ? nghbr
          [
            while [dis > maxl]     ;;if it is too far...
            [
              face turtle ?        ;;turn towards that neighbor...
              fd .005               ;and move towards it until...
              set dis distance turtle ? ;the spring length is acceptable
            ]
          ]
          if member? ? dnghbr      ;;for diagonal neighbors (different maximum length)
          [
            while [dis > maxdl]
            [
              face turtle ?
              fd .005
              set dis distance turtle ?
            ]
          ]
        ]
      ]
    set i i + 1                    ;;work outwards
    ]
end

to constrain-arc                  ;;constrain procedure for triangular mesh
  set i 1
  repeat r
  [
    ask turtles with [j = i]      ;;begins with turtles closest to the pin
      [
        foreach turnnghbr
        [
          set dis distance turtle ? ;;how far is the turtle from that neighbor
          ifelse [j] of self = [j] of myself
          [
            while [dis > maxl]     ;;if it is too far...
            [
              face turtle ?        ;;turn towards that neighbor...
              fd .005               ;and move towards it until...
              set dis distance turtle ? ;the spring length is acceptable
            ]
          ]
          [
            while [dis > maxarcl]
            [
              face turtle ?
              fd .005
              set dis distance turtle ?
            ]
          ]
        ]
      ]
    set i i + 1                    ;;work outwards
    ]
end
@#$#@#$#@
GRAPHICS-WINDOW
0
0
1525
1546
50
50
15.0
1
10
1
1
1
0
1
1
1
-50
50
-50
50
-50
50
1
1
1
ticks
30.0

BUTTON
16
15
159
48
Setup Quadrangular
setup-quad
NIL
1
T
OBSERVER
NIL
NIL
NIL
NIL
1

BUTTON
15
62
138
95
Setup Triangular
setup-tri
NIL
1
T
OBSERVER
NIL
NIL
NIL
NIL
1

BUTTON
16
108
102
141
Setup Arc
setup-arc
NIL
1
T
OBSERVER
NIL
NIL
NIL
NIL
1

BUTTON
172
14
313
47
Move
move
T
1
T
OBSERVER
NIL
NIL
NIL
NIL
1

SLIDER
15
166
187
199
Scale
Scale
0
10
1
1
1
NIL
HORIZONTAL

SLIDER
15
214
187
247
Arc_Scale
Arc_Scale
0
100
16
1
1
NIL
HORIZONTAL

SLIDER
16
260
188
293
Friction
Friction
0
1
0.11
.01
1
NIL
HORIZONTAL

MONITOR
377
17
455
62
Mass Points
trtlcnt
0
1
11

MONITOR
378
78
435
123
Springs
sprngcnt
0
1
11

MONITOR
379
136
446
181
Equations
eqcnt
0
1
11

MONITOR
381
195
502
240
Computational Time
comptime
3
1
11

@#$#@#$#@
## WHAT IS IT?

(a general understanding of what the model is trying to show or explain)

## HOW IT WORKS

(what rules the agents use to create the overall behavior of the model)

## HOW TO USE IT

(how to use the model, including a description of each of the items in the Interface tab)

## THINGS TO NOTICE

(suggested things for the user to notice while running the model)

## THINGS TO TRY

(suggested things for the user to try to do (move sliders, switches, etc.) with the model)

## EXTENDING THE MODEL

(suggested things to add or change in the Code tab to make the model more complicated, detailed, accurate, etc.)

## NETLOGO FEATURES

(interesting or unusual features of NetLogo that the model uses, particularly in the Code tab; or where workarounds were needed for missing features)

## RELATED MODELS

(models in the NetLogo Models Library and elsewhere which are of related interest)

## CREDITS AND REFERENCES

(a reference to the model's URL on the web if it has one, as well as any other necessary credits, citations, and links)
@#$#@#$#@
default
true
0
Polygon -7500403 true true 150 5 40 250 150 205 260 250

airplane
true
0
Polygon -7500403 true true 150 0 135 15 120 60 120 105 15 165 15 195 120 180 135 240 105 270 120 285 150 270 180 285 210 270 165 240 180 180 285 195 285 165 180 105 180 60 165 15

arrow
true
0
Polygon -7500403 true true 150 0 0 150 105 150 105 293 195 293 195 150 300 150

box
false
0
Polygon -7500403 true true 150 285 285 225 285 75 150 135
Polygon -7500403 true true 150 135 15 75 150 15 285 75
Polygon -7500403 true true 15 75 15 225 150 285 150 135
Line -16777216 false 150 285 150 135
Line -16777216 false 150 135 15 75
Line -16777216 false 150 135 285 75

bug
true
0
Circle -7500403 true true 96 182 108
Circle -7500403 true true 110 127 80
Circle -7500403 true true 110 75 80
Line -7500403 true 150 100 80 30
Line -7500403 true 150 100 220 30

butterfly
true
0
Polygon -7500403 true true 150 165 209 199 225 225 225 255 195 270 165 255 150 240
Polygon -7500403 true true 150 165 89 198 75 225 75 255 105 270 135 255 150 240
Polygon -7500403 true true 139 148 100 105 55 90 25 90 10 105 10 135 25 180 40 195 85 194 139 163
Polygon -7500403 true true 162 150 200 105 245 90 275 90 290 105 290 135 275 180 260 195 215 195 162 165
Polygon -16777216 true false 150 255 135 225 120 150 135 120 150 105 165 120 180 150 165 225
Circle -16777216 true false 135 90 30
Line -16777216 false 150 105 195 60
Line -16777216 false 150 105 105 60

car
false
0
Polygon -7500403 true true 300 180 279 164 261 144 240 135 226 132 213 106 203 84 185 63 159 50 135 50 75 60 0 150 0 165 0 225 300 225 300 180
Circle -16777216 true false 180 180 90
Circle -16777216 true false 30 180 90
Polygon -16777216 true false 162 80 132 78 134 135 209 135 194 105 189 96 180 89
Circle -7500403 true true 47 195 58
Circle -7500403 true true 195 195 58

circle
false
0
Circle -7500403 true true 0 0 300

circle 2
false
0
Circle -7500403 true true 0 0 300
Circle -16777216 true false 30 30 240

cow
false
0
Polygon -7500403 true true 200 193 197 249 179 249 177 196 166 187 140 189 93 191 78 179 72 211 49 209 48 181 37 149 25 120 25 89 45 72 103 84 179 75 198 76 252 64 272 81 293 103 285 121 255 121 242 118 224 167
Polygon -7500403 true true 73 210 86 251 62 249 48 208
Polygon -7500403 true true 25 114 16 195 9 204 23 213 25 200 39 123

cylinder
false
0
Circle -7500403 true true 0 0 300

dot
false
0
Circle -7500403 true true 90 90 120

face happy
false
0
Circle -7500403 true true 8 8 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Polygon -16777216 true false 150 255 90 239 62 213 47 191 67 179 90 203 109 218 150 225 192 218 210 203 227 181 251 194 236 217 212 240

face neutral
false
0
Circle -7500403 true true 8 7 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Rectangle -16777216 true false 60 195 240 225

face sad
false
0
Circle -7500403 true true 8 8 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Polygon -16777216 true false 150 168 90 184 62 210 47 232 67 244 90 220 109 205 150 198 192 205 210 220 227 242 251 229 236 206 212 183

fish
false
0
Polygon -1 true false 44 131 21 87 15 86 0 120 15 150 0 180 13 214 20 212 45 166
Polygon -1 true false 135 195 119 235 95 218 76 210 46 204 60 165
Polygon -1 true false 75 45 83 77 71 103 86 114 166 78 135 60
Polygon -7500403 true true 30 136 151 77 226 81 280 119 292 146 292 160 287 170 270 195 195 210 151 212 30 166
Circle -16777216 true false 215 106 30

flag
false
0
Rectangle -7500403 true true 60 15 75 300
Polygon -7500403 true true 90 150 270 90 90 30
Line -7500403 true 75 135 90 135
Line -7500403 true 75 45 90 45

flower
false
0
Polygon -10899396 true false 135 120 165 165 180 210 180 240 150 300 165 300 195 240 195 195 165 135
Circle -7500403 true true 85 132 38
Circle -7500403 true true 130 147 38
Circle -7500403 true true 192 85 38
Circle -7500403 true true 85 40 38
Circle -7500403 true true 177 40 38
Circle -7500403 true true 177 132 38
Circle -7500403 true true 70 85 38
Circle -7500403 true true 130 25 38
Circle -7500403 true true 96 51 108
Circle -16777216 true false 113 68 74
Polygon -10899396 true false 189 233 219 188 249 173 279 188 234 218
Polygon -10899396 true false 180 255 150 210 105 210 75 240 135 240

house
false
0
Rectangle -7500403 true true 45 120 255 285
Rectangle -16777216 true false 120 210 180 285
Polygon -7500403 true true 15 120 150 15 285 120
Line -16777216 false 30 120 270 120

leaf
false
0
Polygon -7500403 true true 150 210 135 195 120 210 60 210 30 195 60 180 60 165 15 135 30 120 15 105 40 104 45 90 60 90 90 105 105 120 120 120 105 60 120 60 135 30 150 15 165 30 180 60 195 60 180 120 195 120 210 105 240 90 255 90 263 104 285 105 270 120 285 135 240 165 240 180 270 195 240 210 180 210 165 195
Polygon -7500403 true true 135 195 135 240 120 255 105 255 105 285 135 285 165 240 165 195

line
true
0
Line -7500403 true 150 0 150 300

line half
true
0
Line -7500403 true 150 0 150 150

pentagon
false
0
Polygon -7500403 true true 150 15 15 120 60 285 240 285 285 120

person
false
0
Circle -7500403 true true 110 5 80
Polygon -7500403 true true 105 90 120 195 90 285 105 300 135 300 150 225 165 300 195 300 210 285 180 195 195 90
Rectangle -7500403 true true 127 79 172 94
Polygon -7500403 true true 195 90 240 150 225 180 165 105
Polygon -7500403 true true 105 90 60 150 75 180 135 105

plant
false
0
Rectangle -7500403 true true 135 90 165 300
Polygon -7500403 true true 135 255 90 210 45 195 75 255 135 285
Polygon -7500403 true true 165 255 210 210 255 195 225 255 165 285
Polygon -7500403 true true 135 180 90 135 45 120 75 180 135 210
Polygon -7500403 true true 165 180 165 210 225 180 255 120 210 135
Polygon -7500403 true true 135 105 90 60 45 45 75 105 135 135
Polygon -7500403 true true 165 105 165 135 225 105 255 45 210 60
Polygon -7500403 true true 135 90 120 45 150 15 180 45 165 90

sheep
false
0
Rectangle -7500403 true true 151 225 180 285
Rectangle -7500403 true true 47 225 75 285
Rectangle -7500403 true true 15 75 210 225
Circle -7500403 true true 135 75 150
Circle -16777216 true false 165 76 116

square
false
0
Rectangle -7500403 true true 30 30 270 270

square 2
false
0
Rectangle -7500403 true true 30 30 270 270
Rectangle -16777216 true false 60 60 240 240

star
false
0
Polygon -7500403 true true 151 1 185 108 298 108 207 175 242 282 151 216 59 282 94 175 3 108 116 108

target
false
0
Circle -7500403 true true 0 0 300
Circle -16777216 true false 30 30 240
Circle -7500403 true true 60 60 180
Circle -16777216 true false 90 90 120
Circle -7500403 true true 120 120 60

tree
false
0
Circle -7500403 true true 118 3 94
Rectangle -6459832 true false 120 195 180 300
Circle -7500403 true true 65 21 108
Circle -7500403 true true 116 41 127
Circle -7500403 true true 45 90 120
Circle -7500403 true true 104 74 152

triangle
false
0
Polygon -7500403 true true 150 30 15 255 285 255

triangle 2
false
0
Polygon -7500403 true true 150 30 15 255 285 255
Polygon -16777216 true false 151 99 225 223 75 224

truck
false
0
Rectangle -7500403 true true 4 45 195 187
Polygon -7500403 true true 296 193 296 150 259 134 244 104 208 104 207 194
Rectangle -1 true false 195 60 195 105
Polygon -16777216 true false 238 112 252 141 219 141 218 112
Circle -16777216 true false 234 174 42
Rectangle -7500403 true true 181 185 214 194
Circle -16777216 true false 144 174 42
Circle -16777216 true false 24 174 42
Circle -7500403 false true 24 174 42
Circle -7500403 false true 144 174 42
Circle -7500403 false true 234 174 42

turtle
true
0
Polygon -10899396 true false 215 204 240 233 246 254 228 266 215 252 193 210
Polygon -10899396 true false 195 90 225 75 245 75 260 89 269 108 261 124 240 105 225 105 210 105
Polygon -10899396 true false 105 90 75 75 55 75 40 89 31 108 39 124 60 105 75 105 90 105
Polygon -10899396 true false 132 85 134 64 107 51 108 17 150 2 192 18 192 52 169 65 172 87
Polygon -10899396 true false 85 204 60 233 54 254 72 266 85 252 107 210
Polygon -7500403 true true 119 75 179 75 209 101 224 135 220 225 175 261 128 261 81 224 74 135 88 99

wheel
false
0
Circle -7500403 true true 3 3 294
Circle -16777216 true false 30 30 240
Line -7500403 true 150 285 150 15
Line -7500403 true 15 150 285 150
Circle -7500403 true true 120 120 60
Line -7500403 true 216 40 79 269
Line -7500403 true 40 84 269 221
Line -7500403 true 40 216 269 79
Line -7500403 true 84 40 221 269

wolf
false
0
Polygon -7500403 true true 135 285 195 285 270 90 30 90 105 285
Polygon -7500403 true true 270 90 225 15 180 90
Polygon -7500403 true true 30 90 75 15 120 90
Circle -1 true false 183 138 24
Circle -1 true false 93 138 24

x
false
0
Polygon -7500403 true true 270 75 225 30 30 225 75 270
Polygon -7500403 true true 30 75 75 30 270 225 225 270

@#$#@#$#@
NetLogo 3D 5.0.1
@#$#@#$#@
@#$#@#$#@
@#$#@#$#@
@#$#@#$#@
@#$#@#$#@
default
0.0
-0.2 0 1.0 0.0
0.0 1 1.0 0.0
0.2 0 1.0 0.0
link direction
true
0
Line -7500403 true 150 150 90 180
Line -7500403 true 150 150 210 180

@#$#@#$#@
0
@#$#@#$#@